Inhalte

# Funktion MITTELWERTWENN

Ergibt das arithmetische Mittel aller Zellen eines Bereichs, die eine vorgegebene Bedingung erfüllen. Die Funktion MITTELWERTWENN addiert alle Werte, welche die Bedingung erfüllen, und teilt die Summe durch die Anzahl der zutreffenden Zellen.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

### Syntax

MITTELWERTWENN(Bereich; Kriterium [; Mittelwertbereich ])

Bereich – erforderliches Argument. Ein Zellbereich, der Name eines benannten Bereichs oder eine Zeilen-/Spaltenüberschrift, mit den zu mittelnden Zahlen oder dem Text für die Bedingung.

Kriterium: Ein Kriterium ist ein einzelner Zellbezug, eine Zahl oder ein Text. Es wird für Vergleiche mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

- Eine Zahl oder ein logischer Wert. Ein übereinstimmender Zelleninhalt entspricht dem Zahlenwert oder dem logischen Wert.

- Ein Wert, der mit einem Vergleichs-Operator beginnt (<, <=, =, >, >= oder <>).

  Bei = gilt: Wenn der Wert leer ist, stimmt er mit leeren Zellen überein.

  Bei <> gilt: Wenn der Wert leer ist, stimmt er mit nicht leeren Zellen überein.

  Bei <> gilt: Wenn der Wert nicht leer ist, stimmt er mit jedem Zellinhalt außer dem Wert überein, einschließlich leerer Zellen.

  Hinweis: "=0" stimmt nicht mit leeren Zellen überein.

  Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann und die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen aktiviert ist, wird mit dem gesamten Zellinhalt verglichen, wenn nicht aktiviert, wird mit jedem Teil des Felds verglichen, der den Kriterien entspricht. Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann, trifft die Eigenschaft zu.

- Anderer Textwert. Wenn die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen wahr ist, wird der Vergleich mit dem gesamten Zellinhalt durchgeführt, wenn falsch, wird der Vergleich mit jedem Teil des Felds durchgeführt, der den Kriterien entspricht. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (falls in den Berechnungsoptionen aktiviert).

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter LibreOffice – Einstellungen Extras – Optionen… – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

Mittelwertbereich – optional. Ist ein Bereich mit Werten, für die der Mittelwert berechnet wird.

Wenn Mittelwertbereich nicht angegeben ist, wird Bereich für beides, die Berechnung des Mittelwerts und die Prüfung der Bedingung, verwendet. Wenn Mittelwertbereich angegeben ist, wird Bereich nur für die Prüfung der Bedingung und Mittelwertbereich nur für die Berechnung des Mittelwerts verwendet.

Wenn einzelne Zellen des Bereichs für die Berechnung des Mittelwerts leer sind oder Text enthalten, ignoriert die Funktion MITTELWERTWENN diese Zellen.
Wenn der gesamte Bereich leer ist, nur Text enthält oder alle Werte des Bereichs nicht die Bedingung erfüllen (oder eine Kombinationen dieser), ergibt die Funktion den Fehlerwert #DIV/0!.

### Beispiele

Betrachten Sie folgende Tabelle

| A | B | C
1 | Produktname | Sales | Revenue
2 | Buntstift | 20 | 65
3 | Stift | 35 | 85
4 | Schulbuch | 20 | 190
5 | Buch | 17 | 180
6 | Buntstift-Set | nicht | nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

#### Einfache Verwendung

=MITTELWERTWENN(B2:B6;"<35")

Berechnet den Mittelwert der Werte im Bereich B2:B6, die kleiner als 35 sind. Ergibt 19, da die zweite Zeile nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;"<"&MAX(B2:B6))

Berechnet den Mittelwert der Werte desselben Bereichs, die kleiner als der Maximalwert dieses Bereichs sind. Ergibt 19, da der größte Wert (in der zweiten Zeile) nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN;">"&KKLEINSTE(B2:B6;1))

Berechnet den Mittelwert der Werte desselben Bereichs, die größer als der erst-kleinste Wert dieses Bereichs sind. Ergibt 25, da der erst-kleinste Wert (in der vierten Zeile) nicht in die Berechnung mit einbezogen wird.

#### Verwendung von Mittelwertbereich

=MITTELWERTWENN(B2:B6;"<35";C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 kleiner als 35 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 145, da die zweite Zeile nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;">"&MIN(B2:B6);C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 größer als der größte Wert in B2:B6 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 113,3, da die vierte Zeile (die den größten Wert im Bereich B2:B6 enthält) nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;"<"&KGRÖSSTE(B2:B6;2);C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 kleiner als der zweit-kleinste Wert im Bereich B2:B6 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 180, da nur die vierte Zeile in die Berechnung mit einbezogen wird.

#### Verwendung mit regulären Ausdrücken

=MITTELWERTWENN(A2:A6;"stift";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 den Ausdruck „stift“ enthalten, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 35, da nur die zweite Zeile in die Berechnung mit einbezogen wird. Die Suche erfolgt in Bereich A2:A6, aber die Werte stammen aus dem Bereich B2:B6.

=MITTELWERTWENN(A2:A6;".*stift";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 irgendwie beginnen und auf „stift“ enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 27,5, da zusätzlich „Bleistift“ die Bedingung erfüllt und somit die erste und die zweite Zeile in die Berechnung mit einbezogen werden.

=MITTELWERTWENN(A2:A6;".*buch.*";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 „buch“ enthalten sowie irgendwie starten und enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 18,5, da nur die dritte und die vierte Zeile in die Berechnung mit einbezogen werden.

#### Bezüge zu einer Zelle mit einer Bedingung

Um die Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion MITTELWERTWENN einen Bezug zur Zelle anzugeben.

=MITTELWERTWENN(A2:A6;".*"&E2&".*";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 den Ausdruck aus Zelle E2 enthalten sowie irgendwie starten und enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Wenn E2 = buch, ergibt die Funktion 18,5.

=MITTELWERTWENN(B2:B6;"<"&E2;C2:C6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 kleiner als der in Zelle E2 enthalte Wert sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Wenn E2 = 35, ergibt die Funktion 145.

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

Verwandte Themen

Wikiseite zu MITTELWERTWENN.

MITTELWERT, MITTELWERTA, MITTELABW

ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS, SUMMEWENNS

Liste der regulären Ausdrücke